This is an example .bat file that’ll discover your windows version and copy the config file from a specified location.

@echo off
REM Change this to the location for the config file. The user that runs the
REM .bat file have to have access to the share. The recommended solution is to copy
REM a modified config file to the same directory as the shared definition file.
SET NAAWSHARE=\\server\naaw

REM The local location of Norman Ad-Aware.
SET NAAWPATH=C:\Program Files\Norman\Norman Ad-Aware SE Professional

VER | FIND /i "Windows 95" >NUL
IF NOT ERRORLEVEL 1 GOTO WIN95

VER | FIND /i "Windows 98" >NUL
IF NOT ERRORLEVEL 1 GOTO WIN98ME

VER | FIND /i "Windows Millenium" >NUL
IF NOT ERRORLEVEL 1 GOTO WIN98ME

VER | FIND /i "Windows XP" >NUL
IF NOT ERRORLEVEL 1 GOTO WIN2000XP

VER | FIND /i "Windows 2000" >NUL
IF NOT ERRORLEVEL 1 GOTO WIN2000XP

GOTO UNKNOWN

:WIN95
REM Ad-Aware doesn’t support this windows version.
GOTO END

:WIN98ME
xcopy "%NAAWSHARE%\settings.awc" "%NAAWPATH%\" /y /h /k /r /q
GOTO END

:WIN2000XP
xcopy "%NAAWSHARE%\settings.awc" "%APPDATA%\Norman\Ad-Aware\" /y /h /k /r /q
GOTO END

:UNKNOWN
REM If you want to do something if the version check fails you can do it here.

:END